fox32-hw/flake.nix

{
  description = "fox32 on FPGA";

  inputs = {
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, nixpkgs, flake-utils }:
    flake-utils.lib.eachDefaultSystem (sys:
      let pkgs = nixpkgs.legacyPackages.${sys};

          verilator = import ./verilator.nix pkgs ;
          yosys = pkgs.yosys;

          vflags = ''-Wpedantic -Wwarn-lint -Wwarn-style -Wno-PINCONNECTEMPTY -Wno-BLKSEQ -CFLAGS "-Wpedantic -std=c++20"'';

          verilate-src = cmd: ''
            cp -r ${./src} ./src
            cp -r ${./simulation} ./simulation
            find ./src/ -name '*.v' -exec ${verilator}/bin/verilator ${vflags} ${cmd} {} +
          '';

          lint = pkgs.runCommand "lint" {} ''
             ${verilate-src "--lint-only"}
             echo "compiler didn't get angry :3"
             : 3 > $out
          '';

          alu-test = pkgs.runCommandCC "alu-test" {} ''
            ${verilate-src "--cc --build --exe ./simulation/tester.cpp ./simulation/test_alu.cpp -top alu"}
            mv obj_dir "$out"
            mkdir "$out/bin" && cp "$out/Valu" "$out/bin/alu-test"
          '';

          alu-test-trace = pkgs.runCommandCC "alu-test-trace" {} ''
            ${verilate-src "--cc --build --exe --trace -CFLAGS -DTRACE=1 ./simulation/tester.cpp ./simulation/test_alu.cpp -top alu"}
            mv obj_dir "$out"
            mkdir "$out/bin" && cp "$out/Valu" "$out/bin/alu-sim"
            $out/bin/alu-sim $out/trace.vcd
            echo "${pkgs.gtkwave}/bin/gtkwave $out/trace.vcd" > $out/bin/alu-test-trace
            chmod u+x $out/bin/alu-test-trace
          '';

          synth = pkgs.runCommandCC "synth" {} ''
            mkdir -p "$out"
            find ${./src} -name '*.v' -exec ${yosys}/bin/yosys -f ' -sv' -Q -p "synth_ice40 -top topmost -json $out/synth.json" {} +
          '';

          pnr-interactive = pkgs.writeScriptBin "pnr-interactive" ''
            ${pkgs.nextpnrWithGui}/bin/nextpnr-ice40 --up5k --package sg48 --pcf ${./fpga-files/rot.pcf} --json ${synth}/synth.json --gui
          '';

          deps = [
            yosys pkgs.nextpnrWithGui pkgs.icestorm verilator pkgs.gtkwave
          ];
      in rec {
        packages.verilator = verilator;

        packages.lint = lint;

        packages.alu-test = alu-test;
        packages.alu-test-trace = alu-test-trace;

        packages.synth = synth;
        packages.pnr-interactive = pnr-interactive;

        devShells.default = pkgs.mkShell { packages = deps; };
      }
    );
}