nixos-server/flake.nix

{
  description = "NixOs configuration for my server";

  inputs = {
    nixpkgs.url = "github:NixOs/nixpkgs/nixos-23.11";
    nixos-config.url = "git+https://githug.xyz/rachel/nixos-config";
  };

  outputs = { self, nixpkgs, nixos-config, ... }: 
    let nix-config-module =
        {
          nix.registry.nixpkgs.flake = nixpkgs;
          system.configurationRevision = nixpkgs.lib.mkIf (self ? rev) self.rev;
        };
        keyboard-module =
        {
          console = {
            useXkbConfig = true;
          };

          services.xserver = {
            xkb = {
              layout = "fox";
              extraLayouts.fox = {
                description = "Layout suitable to be used by a fox";
                languages = [ "se" ];
                symbolsFile = nixos-config.keyboardLayouts.fox;
              };
            };
          };
        };
    in {
      nixosConfigurations.cafe = nixpkgs.lib.nixosSystem {
        system = "x86_64-linux";
        modules = [
          nix-config-module
          keyboard-module
          ./host.nix
        ];
      };
    };
}